Создать HTML-список файлов из каталога и всех его подкаталогов
Создание HTML-списка, состоящего только из имён файлов (без пути к ним и без папок) из каталога и всех его подкаталогов, отсортированного по алфавиту, в командной строке Windows. Список затем выводится в HTML-документ, также создаваемый в процессе.
Код для BAT файла:
@ECHO OFF
SETLOCAL EnableDelayedExpansion
:: Установить каталог, с которым будет вестись работа
SET "DIR=C:\TEST\"
:: Создание временного файла для промежуточных результатов
SET "TMP=%TEMP%\FILES_%RANDOM%.TMP"
:: Формирование верхней части HTML-документа
ECHO ^<^^!DOCTYPE html^> > files.htm
ECHO ^<html^> >> files.htm
ECHO ^<head^> >> files.htm
ECHO ^<title^>%DIR%^</title^> >> files.htm
ECHO ^</head^> >> files.htm
ECHO ^<body^> >> files.htm
:: Создание и сортировка списка имён файлов
ECHO ^<ul^> >> files.htm
FOR /R "%DIR%" %%G IN (*) DO (
ECHO ^<li^>%%~NXG^</li^>
) >> "%TMP%"
SORT "%TMP%" >> files.htm && DEL "%TMP%"
ECHO ^</ul^> >> files.htm
:: Формирование нижней части HTML-документа
ECHO ^</body^> >> files.htm
ECHO ^</html^> >> files.htm
Операционные системы
- Windows